ArrayOfLedArrays.ino

Go to the documentation of this file.

 
// @filter: (board is not ATtiny1604)
 
// ArrayOfLedArrays - see https://github.com/FastLED/FastLED/wiki/Multiple-Controller-Examples for more info on
// using multiple controllers.  In this example, we're going to set up three NEOPIXEL strips on three
// different pins, each strip getting its own CRGB array to be played with, only this time they're going
// to be all parts of an array of arrays.
 
#include <FastLED.h>
 
#define NUM_STRIPS 3
#if FL_PLATFORM_HAS_TINY_MEMORY
// Three 60-pixel arrays alone need 540 B, more than an ATtiny85 owns.
#define NUM_LEDS_PER_STRIP 4
#else
#define NUM_LEDS_PER_STRIP 60
#endif
CRGB leds[NUM_STRIPS][NUM_LEDS_PER_STRIP];
 
// For mirroring strips, all the "special" stuff happens just in setup.  We
// just addLeds multiple times, once for each strip
void setup() {
  // Add the first NEOPIXEL strip on pin 2.
  FastLED.addLeds<NEOPIXEL, 2>(leds[0], NUM_LEDS_PER_STRIP);
 
  // Add the second NEOPIXEL strip on pin 3.
  FastLED.addLeds<NEOPIXEL, 3>(leds[1], NUM_LEDS_PER_STRIP);
 
  // Add the third NEOPIXEL strip on pin 4.
  FastLED.addLeds<NEOPIXEL, 4>(leds[2], NUM_LEDS_PER_STRIP);
 
}
 
void loop() {
  // This outer loop will go over each strip, one at a time
  for(int x = 0; x < NUM_STRIPS; x++) {
    // This inner loop will go over each led in the current strip, one at a time
    for(int i = 0; i < NUM_LEDS_PER_STRIP; i++) {
      leds[x][i] = CRGB::Red;
      FastLED.show();
      leds[x][i] = CRGB::Black;
      delay(100);
    }
  }
}